ToolbarEventIds 列挙体

Imports Infragistics.Win.UltraWinToolbars

Private Sub button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles button1.Click

    ' Get the toolbar manager's event manager.
    ' The event manager is used to temporarily disable events
    ' to prevent them from being raised. This can be very
    ' convenient in a situation where one or more properties
    ' are being set in code and the events they would normally 
    ' raise would cause unnecessary or counter-productive
    ' code to be executed.
    '
    ' Note: All events are enabled by default.
    Dim eventManager As ToolbarsEventManager

    eventManager = Me.ultraToolbarsManager1.EventManager

    ' Disable the ToolClick event
    eventManager.SetEnabled(ToolbarEventIds.ToolClick, False)

    ' Toggle the 'Checked' property of a state button tool.
    ' Note: This would normally cause the ToolClick event to 
    ' be raised. However, since the above code disabled the event
    ' it won't be raised.
    Dim tool As StateButtonTool

    tool = Me.ultraToolbarsManager1.Tools("StateButtonTool1")
    tool.Checked = Not tool.Checked

    ' Re-enable the ToolClick event
    eventManager.SetEnabled(ToolbarEventIds.ToolClick, True)

    ' The 'AllEventsEnabled' property lets you enable/disable
    ' all events will a single line of code. If any event is 
    ' disabled the 'AllEventsEnabled' property returns false.
    If Not eventManager.AllEventsEnabled Then
        eventManager.AllEventsEnabled = True
    End If

    ' The event manager also exposes an 'IsEnabled' method
    ' to see if an event is enabled or disbled.
    If Not eventManager.IsEnabled(ToolbarEventIds.ToolClick) Then
        eventManager.SetEnabled(ToolbarEventIds.ToolClick, True)
    End If

    ' The status bar event manager also exposes overloaded 
    ' 'IsEnabled' and 'SetEnabled' methods that take an  
    ' event group so that, for example all 'Before' or all
    ' 'After' events can be enabled/disabled. If any event
    ' in the group is disabled the 'IsEnabled' method returns
    ' false.
    If Not eventManager.IsEnabled(EventGroups.BeforeEvents) Then
        eventManager.SetEnabled(EventGroups.BeforeEvents, True)
    End If

    eventManager.SetEnabled(EventGroups.AfterEvents, True)

    ' The 'InProgress' method will return true if the 
    ' specified event is currently being raised. This
    ' is often helpful in methods that can be called
    ' from various points in an application to determine
    ' what is triggering the call.
    If eventManager.InProgress(ToolbarEventIds.ToolClick) Then
        ' ... 
    End If

End Sub